Gproblem.pddl

Goldfinger Problem File

An example problem file for the goldfinger domain is shown below:

 (define (problem goldfinger-2)
   (:domain goldfinger)
   (:objects
     bond - goodchar
     goldfinger - char
     oddbod - badchar
     jill - badchar
     m - char
     london - location
     miami - location
     card-game - card-location
     golf-game - golf-location
   )
   (:init
     (at bond miami)
     (at goldfinger card-game)
     (at jill card-game)
     (at oddbod card-game)
     (at m london)
     (boss m bond)
     (allegiance jill goldfinger)
     (allegiance oddbod goldfinger)
     (assistant goldfinger jill)
     (assistant goldfinger oddbod)
     (alive oddbod)
     (alive jill)
     (be-the-boss goldfinger jill)
     (be-the-boss goldfinger oddbod)
     (enemies bond goldfinger)
     (enemies goldfinger bond)
     (different bond goldfinger)
     (different goldfinger bond)
     (different jill oddbod)
     (different oddbod jill)
     (different oddbod bond)
     (different bond oddbod)
     (feeling-of-power goldfinger low)
   )
   (:goal
   (and
     (feeling-of-power goldfinger high)
   ))
   (:constraints
   (and
     (always (at m london))
     (always (assistant goldfinger jill))
     (sometime (seduced bond jill))
     (sometime-before
       (at bond golf-game)
       (at bond card-game))
     (sometime-after
       (got-mission bond)
       (won-cards bond goldfinger card-game))))
 )